Este tutorial se sumerge en varias formas de usar la función ISNA en Excel para manejar errores #N/A.
Cuando Excel no puede encontrar lo que se le pide, aparece un error #N/A en una celda. Para interceptar y manejar tales errores, puede usar la función ISNA. ¿Cuál es el uso práctico de eso? Esencialmente, ayuda a que sus fórmulas sean más fáciles de usar y sus hojas de trabajo se vean mejor.
Función ISNA en Excel
La función ISNA de Excel se usa para verificar celdas o fórmulas en busca de errores #N/A. El resultado es un valor lógico: VERDADERO si se detecta un error #N/A, FALSO en caso contrario.
La función está disponible en todas las versiones de Excel 2000 a 2021 y Excel 365.
La sintaxis de la función ISNA es tan simple como podría ser:
ISNA(valor)
Donde valor es el valor de la celda o la fórmula que desea verificar en busca de errores #N/A.
Para crear una fórmula ISNA en su forma básica, proporcione una referencia de celda como su único argumento:
=ISNA(A2)
En caso de que la celda a la que se hace referencia contenga un error #N/A, obtendrá VERDADERO. En caso de cualquier otro error, valor o celda en blanco, obtendrá FALSO:
Cómo usar ISNA en Excel
Usar la función ISNA en su forma pura tiene poco sentido práctico. Más a menudo, se usa junto con otras funciones para evaluar el resultado de una determinada fórmula. Para esto, simplemente coloque esa otra fórmula en el argumento de valor de ISNA:
ISNA(tu_fórmula())
En el siguiente conjunto de datos, suponga que desea comparar dos listas (columnas A y D) e identificar los nombres que están presentes en ambas listas y los que aparecen solo en la lista 1.
Para comparar el nombre en A3 con cada nombre en la columna D, la fórmula es:
=MATCH(A3, $D$2:$D$9, 0)
Si se encuentra un valor de búsqueda, la función COINCIDIR devuelve su posición relativa en la matriz de búsqueda; de lo contrario, se produce un error #N/A. Para probar el resultado de MATCH, lo anidamos en ISNA:
=ISNA(MATCH(A3, $D$2:$D$9, 0))
Esta fórmula va a B3 y luego se copia a través de B14.
Ahora, puede ver claramente qué estudiantes han pasado todas las pruebas (no hay un nombre disponible en la columna D > COINCIDIR devuelve #N/A > ISNA devuelve VERDADERO) y cuáles tienen al menos una prueba reprobada (aparece un nombre en la columna D > ningún error > ISNA devuelve FALSO).
Fórmula SI ISNA en Excel
Por diseño, la función ISNA solo puede devolver dos valores booleanos. Para mostrar sus mensajes personalizados, úselo en combinación con la función IF:
SI(ISNA(…), «texto_si_error», «texto_si_no_error»)
Refinando nuestro ejemplo un poco más, averigüemos qué estudiantes del grupo A no reprobaron ninguna prueba y devolvamos «No reprobaron pruebas» para ellos. Para los estudiantes restantes, devolveremos «Reprobado». Para hacer esto, incruste la fórmula ISNA MATCH en la prueba lógica de IF, de modo que IF se convierta en la función más externa:
=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "No failed tests", "Failed")
Los resultados se ven mucho mejores y más intuitivos ahora, ¿de acuerdo?
Cómo usar ISNA en Excel con BUSCARV
La combinación IF ISNA es una solución universal que se puede usar con cualquier función que busque algo en un conjunto de datos y devuelva un error #N/A cuando no se encuentra un valor de búsqueda.
La sintaxis de la función ISNA con BUSCARV es la siguiente:
SI(ISNA(BUSCARV(…), «texto_personalizado», BUSCARV(…))
Traducido a un lenguaje humano, dice: si VLOOKUP da como resultado un error #N/A, devuelva el texto personalizado; de lo contrario, devuelva el resultado de VLOOKUP.
En nuestra tabla de muestra, suponga que desea devolver las materias en las que los estudiantes reprobaron las pruebas. Para aquellos que hayan pasado todas las pruebas con éxito, se mostrará «No hay pruebas fallidas».
Para buscar los temas, construimos esta fórmula clásica de BUSCARV:
=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)
Y luego anídelo en la fórmula genérica IF ISNA discutida anteriormente:
=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "No failed tests", VLOOKUP(A3, $D$3:$E$9, 2, FALSE))
En Excel 2013 y versiones posteriores, puede utilizar la función IFNA para detectar y manejar errores #N/A. Esto hace que su fórmula sea más corta y más fácil de leer.
Como ejemplo, reemplazamos los errores #N/A con guiones («-«) y obtenemos esta elegante solución:
=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")
Los usuarios de Excel 365 y 2021 no necesitan ninguna función contenedora, ya que el sucesor moderno de BUSCARV, la función BUSCARX, puede manejar los errores #N/A de forma nativa:
=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")
El resultado será exactamente el mismo que se muestra en la captura de pantalla anterior.
Fórmula SUMPRODUCT ISNA para contar errores #N/A
Para contar errores #N/A en un cierto rango, use la función ISNA junto con SUMPRODUCT de esta manera:
SUMAPRODUCTO(–ISNA(rango))
Aquí, ISNA devuelve una matriz de valores VERDADERO y FALSO, la doble negación (–) convierte los valores lógicos en 1 y 0, y SUMPRODUCT suma el resultado.
Por ejemplo, para averiguar cuántos estudiantes tuvieron éxito en todas las pruebas, modifique la fórmula COINCIDIR para un rango de valores de búsqueda (A3:A14) y anímela en ISNA:
=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0)))
La fórmula determina que 9 estudiantes no tienen exámenes reprobados, es decir, la función COINCIDIR devuelve 9 errores #N/A:
Así es como se crean y usan fórmulas ISNA en Excel. ¡Gracias por leer y espero verte en nuestro blog la próxima semana!
(archivo .xlsx)