¿Obtiene muchos errores #N/A en sus hojas de trabajo y tiene curiosidad por saber si hay una forma de mostrar un texto personalizado en su lugar? La fórmula de IFNA es la solución que necesitas.
Cuando una fórmula de Excel no puede identificar o encontrar algo, arroja el error #N/A. Para detectar un error de este tipo y reemplazarlo con un mensaje fácil de usar, puede usar la función IFNA. En otras palabras, #N/A es la forma en que Excel dice que el valor que está buscando no está presente en el conjunto de datos al que se hace referencia. IFNA es su forma de atrapar y manejar ese error.
Función IFNA en Excel
La función IFNA de Excel está diseñada para detectar y manejar errores #N/A. Si una fórmula se evalúa como #N/A, IFNA atrapa ese error y lo reemplaza con un valor personalizado que especifique; de lo contrario, devuelve un resultado normal de la fórmula.
sintaxis IFNA
La sintaxis de la función IFNA es la siguiente:
IFNA(valor, valor_si_na)
Dónde:
Valor (obligatorio): la fórmula, el valor o la referencia para comprobar si hay un error #N/A.
Valor_si_na (obligatorio): el valor que se devolverá si se detecta un error #N/A.
Notas de uso
- La función IFNA solo maneja #N/A sin suprimir ningún otro error.
- Si el argumento de valor es un fórmula matricialIFNA devuelve una matriz de resultados, uno por celda, como se muestra en este ejemplo.
Disponibilidad de IFNA
La función IFNA se introdujo en Excel 2013 y está disponible en todas las versiones posteriores, incluidas Excel 2016, Excel 2019, Excel 2021 y Microsoft 365.
En versiones anteriores, puede detectar errores #N/A utilizando las funciones IF e ISNA juntas.
Cómo usar la función IFNA en Excel
Para usar IFNA en Excel de manera efectiva, siga este enfoque genérico:
- En el primer argumento (valor), coloque una fórmula afectada por el error #N/A.
- En el segundo argumento (value_if_na), escriba el texto que desea devolver en lugar de la notación de error estándar. Para devolver una celda vacía cuando no se encuentra nada, proporcione una cadena vacía (‘»»).
Regresar texto personalizadola fórmula genérica es:
IFNA(fórmula(), «texto personalizado»)
para devolver un celda en blancola fórmula genérica es:
IFNA(fórmula(), «»)
Veamos cómo funciona en un ejemplo simple. En la siguiente tabla, suponga que desea saber cómo se clasifica el puntaje de un estudiante determinado entre otros. Dado que los datos están ordenados por la columna Puntuación de mayor a menor, la clasificación coincidirá con la posición relativa del estudiante en la tabla. Y para obtener la posición, puede usar la función MATCH en su forma más simple:
=MATCH(E1, A2:A10, 0)
Dado que el valor de búsqueda (Neal) no está disponible en la matriz de búsqueda (A2:A10), se produce un error #N/A.
Al encontrarse con este error, los usuarios inexpertos pueden pensar que hay algún problema con la fórmula y usted, como creador del libro de trabajo, recibirá muchas preguntas. Para evitar esto, puede indicar explícitamente que la fórmula es correcta, simplemente no puede encontrar el valor que se le pide que busque. Entonces, anida la fórmula COINCIDIR en el primer argumento de IFNA y, en el segundo argumento, escribe tu texto personalizado, «No encontrado» en nuestro caso:
=IFNA(MATCH(E1, A2:A10, 0), "Not found")
Ahora, en lugar de la notación de error estándar, se muestra su propio texto en una celda, informando a los usuarios que el valor de búsqueda no está presente en el conjunto de datos:
Cómo usar IFNA con BUSCARV
La mayoría de las veces, el error #N/A ocurre en funciones que buscan algo como BUSCARV, BUSCARH, BUSCAR y COINCIDIR. Los siguientes ejemplos cubren algunos casos de uso típicos.
Ejemplo 1. Fórmula básica IFNA VLOOKUP
Para atrapar los errores #N/A que ocurren cuando BUSCARV no puede encontrar una coincidencia, verifique su resultado usando IFNA y especifique el valor que se mostrará en lugar del error. La práctica común es envolver la función IFNA alrededor de su fórmula BUSCARV existente usando esta sintaxis:
IFNA(BUSCARV(), «su texto»)
En nuestra tabla de muestra, suponga que desea recuperar la puntuación de un estudiante en particular (E1). Para esto, está utilizando esta fórmula clásica de BUSCARV:
=VLOOKUP(E1, A2:B10, 2, FALSE)
El problema es que Neal no tomó el examen, por lo tanto, su nombre no está en la lista y, obviamente, BUSCARV no encuentra una coincidencia.
Para ocultar el error, envolvemos BUSCARV en IFNA de esta manera:
=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")
Ahora, el resultado no parece tan intimidante para el usuario y es mucho más informativo:
Ejemplo 2. IFNA VLOOKUP para buscar en varias hojas
La función IFNA también es útil para realizar las llamadas búsquedas secuenciales o encadenadas en varias hojas o diferentes libros de trabajo. La idea es anidar algunas fórmulas IFNA(BUSCARV(…)) diferentes una dentro de otra de esta manera:
IFNA(BUSCARV(…), IFNA(BUSCARV(…), IFNA(BUSCARV(…), «No encontrado»)))
Si una BUSCARV principal no encuentra nada, su función IFNA ejecuta la siguiente BUSCARV hasta que se encuentra el valor deseado. Si todas las búsquedas fallan, la fórmula devolverá el texto especificado.
Supongamos que tiene las puntuaciones de diferentes clases enumeradas en diferentes hojas (llamadas Clase A, Clase B y Clase C). Su objetivo es obtener el puntaje de un estudiante en particular, cuyo nombre se ingresa en la celda B1 en su hoja de trabajo actual. Para cumplir con la tarea, haga uso de esta fórmula:
=IFNA(VLOOKUP(B1, 'Class A'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class B'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class C'!A2:B5, 2, FALSE), "Not found")))
La fórmula busca secuencialmente el nombre especificado en tres hojas diferentes en el orden en que se anidan las BUSCARV y trae la primera coincidencia encontrada:
Ejemplo 3. IFNA con ÍNDICE MATCH
De manera similar, IFNA puede detectar errores #N/A generados por otras funciones de búsqueda. Como ejemplo, usémoslo junto con la fórmula INDEX MATCH:
=IFNA(INDEX(B2:B10, MATCH(E1, A2:A10, 0)), "Not found")
La esencia de la fórmula es la misma que en todos los ejemplos anteriores: INDEX MATCH realiza una búsqueda e IFNA evalúa el resultado y detecta un error #N/A si no se encuentra el valor de referencia.
IFNA para devolver múltiples resultados
En caso de que la función interna (es decir, la fórmula colocada en el argumento del valor) devuelva múltiples valores, IFNA probará cada valor devuelto individualmente y generará una matriz de resultados. Por ejemplo:
=IFNA(VLOOKUP(D2:D4, A2:B10, 2, FALSE), "Not found")
En Dynamic Array Excel (Microsoft 365 y Excel 2021), una fórmula regular en la celda superior (E2) derrama todos los resultados en las celdas vecinas automáticamente (en términos de Excel, se llama rango de derrame).
En las versiones predinámicas (Excel 2019 y anteriores), se puede lograr un efecto similar utilizando una fórmula de matriz de celdas múltiples, que se completa con el atajo Ctrl + Shift + Enter.
¿Cuál es la diferencia entre IFNA e IFERROR?
Dependiendo de la causa raíz del problema, una fórmula de Excel puede desencadenar diferentes errores como #N/A, #NOMBRE, #VALOR, #REF, #DIV/0, #NUM y otros. La función IFERROR detecta todos esos errores, mientras que IFNA se limita solo a #N/A. ¿Cuál es mejor elegir? Eso depende de la situación.
Si quieres reprimir cualquier tipo de error, luego use la función IFERROR. Es especialmente útil en cálculos complejos cuando una fórmula incluye varias funciones que pueden generar diferentes errores.
Con funciones de búsquedaserá mejor que use IFNA, ya que muestra un resultado personalizado solo cuando no se encuentra un valor de búsqueda y no oculta los problemas subyacentes con la fórmula en sí.
Para ilustrar la diferencia, traigamos de vuelta nuestro básico Fórmula IFNA BUSCARV y «accidentalmente» escribe mal el nombre de la función (BUSCARV en lugar de BUSCARV).
=IFNA(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")
IFNA no suprime este error, por lo que puede ver claramente que algo anda mal con uno de los nombres de función:
Ahora, veamos qué pasa si usas IFERROR:
=IFERROR(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")
Hmm… dice que Olivia no hizo el examen, ¡lo cual no es cierto! Esto se debe a que la función IFERROR atrapa el #NOMBRE? error y devuelve el texto personalizado en su lugar. En esta situación, no solo devuelve información incorrecta, sino que también oscurece el problema con la fórmula.
Así es como se usa la fórmula IFNA en Excel. ¡Gracias por leer y espero verte en nuestro blog la próxima semana!
(archivo .xlsx)