El tutorial muestra cómo usar ISBLANK y otras funciones para identificar celdas en blanco en Excel y tomar diferentes acciones dependiendo de si una celda está vacía o no.
Hay muchas situaciones en las que necesita verificar si una celda está vacía o no. Por ejemplo, si la celda está en blanco, es posible que desee sumar, contar, copiar un valor de otra celda o no hacer nada. En estos escenarios, ISBLANK es la función adecuada para usar, a veces sola, pero con mayor frecuencia en combinación con otras funciones de Excel.
Función Excel ESBLANCO
La función ISBLANK en Excel verifica si una celda está en blanco o no. Al igual que otras funciones IS, siempre devuelve un valor booleano como resultado: VERDADERO si una celda está vacía y FALSO si una celda no está vacía.
La sintaxis de ISBLANK asume solo un argumento:
ESBLANCO (valor)
Donde valor es una referencia a la celda que desea probar.
Por ejemplo, para averiguar si la celda A2 es vacíousa esta fórmula:
=ISBLANK(A2)
Para comprobar si A2 es no vacíoutilice ESBLANCO junto con la función NO, que devuelve el valor lógico inverso, es decir, VERDADERO para los que no son espacios en blanco y FALSO para los espacios en blanco.
=NOT(ISBLANK(A2))
Copie las fórmulas en unas pocas celdas más y obtendrá este resultado:
ISBLANK en Excel – cosas para recordar
El punto principal que debe tener en cuenta es que la función Excel ISBLANK identifica células verdaderamente vacíases decir, celdas que no contienen absolutamente nada: ni espacios, ni tabuladores, ni retornos de carro, nada que solo aparezca en blanco en una vista.
Para una celda que parece estar en blanco, pero en realidad no lo está, una fórmula ES EN BLANCO devuelve FALSO. Este comportamiento ocurre si una celda contiene cualquiera de los siguientes:
- Fórmula que devuelve una cadena vacía como IF(A1<>«», A1, «»).
- Cadena de longitud cero importada de una base de datos externa o resultado de una operación de copiar/pegar.
- Espacios, apóstrofes, espacios de no separación ( ), salto de línea u otros caracteres no imprimibles.
Cómo usar ISBLANK en Excel
Para obtener una mayor comprensión de lo que es capaz de hacer la función ISBLANK, echemos un vistazo a algunos ejemplos prácticos.
Fórmula de Excel: si la celda está en blanco, entonces
Dado que Microsoft Excel no tiene un tipo de función IFBLANK incorporada, debe usar IF y ISBLANK juntos para probar una celda y realizar una acción si la celda está vacía.
Aquí está la versión genérica:
SI(ESBLANCO(celda), «si está en blanco», «si no está en blanco»)
Para verlo en acción, verifiquemos si una celda en la columna B (fecha de entrega) tiene algún valor. Si la celda está en blanco, muestra «Abrir»; si la celda no está en blanco, muestra «Completado».
=IF(ISBLANK(B2), "Open", "Completed")
Recuerde que la función ISBLANK solo determina celdas absolutamente en blanco. Si una celda contiene algo invisible para el ojo humano, como una cadena de longitud cero, ISBLANK devolvería FALSO. Para ilustrar esto, por favor, eche un vistazo a la captura de pantalla a continuación. Las fechas en la columna B se extraen de otra hoja con esta fórmula:
=IF(Sheet3!B2<>"",Sheet3!B2,"")
Como resultado, B4 y B6 contienen cadenas vacías («»). Para estas celdas, nuestra fórmula IF ISBLANK arroja «Completado» porque en términos de ISBLANK las celdas no están vacías.
Si su clasificación de «espacios en blanco» incluye celdas que contienen una fórmula que da como resultado un cuerda vacíaluego use =»» para la prueba lógica:
=IF(B2="", "Open", "Completed")
La siguiente captura de pantalla muestra la diferencia:
Fórmula de Excel: si la celda no está en blanco, entonces
Si ha seguido de cerca el ejemplo anterior y ha entendido la lógica de la fórmula, no debería tener dificultades para modificarla para un caso específico en el que solo se debe realizar una acción cuando la celda no está vacía.
Según su definición de «espacios en blanco», elija uno de los siguientes enfoques.
Para identificar solo verdaderamente no en blanco celdas, invierta el valor lógico devuelto por ISBLANK envolviéndolo en NOT:
SI(NO(ESTÁ EN BLANCO(celda)), «si no está en blanco», «»)
O use la fórmula IF ISBLANK ya familiar (tenga en cuenta que, en comparación con la anterior, los valores value_if_true y value_if_false están intercambiados):
SI(ESBLANCO(celda), «», si no está en blanco»)
al pezón cadenas de longitud cero como espacios en blanco, use <>«» para la prueba lógica de IF:
SI (celda <>«», «si no está en blanco», «»)
Para nuestra tabla de muestra, cualquiera de las fórmulas a continuación funcionará de maravilla. Todos devolverán «Completado» en la columna C si una celda en la columna B no está vacía:
=IF(NOT(ISBLANK(B2)), "Completed", "")
=IF(ISBLANK(B2), "", "Completed")
=IF(B2<>"", "Completed", "")
Si la celda está en blanco, déjela en blanco
En ciertos escenarios, es posible que necesite una fórmula de este tipo: si la celda está en blanco, no haga nada, de lo contrario, realice alguna acción. De hecho, no es más que una variación del genérico SI ESTÁ EN BLANCO fórmula discutida anteriormente, en la que proporciona una cadena vacía («») para el argumento valor_si_verdadero y el valor/fórmula/expresión deseado para valor_si_falso.
Para celdas absolutamente en blanco:
SI(ESBLANCO(celda), «», si no está en blanco»)
Para considerar cadenas vacías como espacios en blanco:
SI (celda=»», «», si no está en blanco»)
En la siguiente tabla, suponga que desea hacer lo siguiente:
- Si la columna B está vacía, deje la columna C vacía.
- Si la columna B contiene un número de ventas, calcule la comisión del 10%.
Para hacerlo, multiplicamos la cantidad en B2 por porcentaje y ponemos la expresión en el tercer argumento de SI:
=IF(ISBLANK(B2), "", B2*10%)
O
=IF(B2="", "", B2*10%)
Después de copiar la fórmula a través de la columna C, el resultado es el siguiente:
Si alguna celda en el rango está en blanco, entonces haga algo
En Microsoft Excel, hay algunas formas diferentes de verificar un rango en busca de celdas vacías. Usaremos una declaración IF para generar un valor si hay al menos una celda vacía en el rango y otro valor si no hay ninguna celda vacía. En la prueba lógica, calculamos el número total de celdas vacías en el rango y luego verificamos si el conteo es mayor que cero. Esto se puede hacer con la función COUNTBLANK o COUNTIF:
CONTARBLANCO(rango)>0
CONTAR.SI(rango,»»)>0
O una fórmula SUMPRODUCT un poco más compleja:
SUMAPRODUCTO(–(rango=»»))>0
Por ejemplo, para asignar el estado «Abierto» a cualquier proyecto que tenga uno o más espacios en blanco en las columnas B a D, puede usar cualquiera de las siguientes fórmulas:
=IF(COUNTBLANK(B2:D2)>0,"Open", "")
=IF(COUNTIF(B2:D2,"")>0, "Open", "")
=IF(SUMPRODUCT(--(B2:D2=""))>0, "Open", "")
Nota. Todas estas fórmulas tratan las cadenas vacías como espacios en blanco.
Si todas las celdas en el rango están en blanco, entonces haga algo
Para comprobar si todas las celdas del rango están vacías, utilizaremos el mismo enfoque que en el ejemplo anterior. La diferencia está en la prueba lógica de SI. Esta vez contamos las celdas que no están vacías. Si el resultado es mayor que cero (es decir, la prueba lógica se evalúa como VERDADERO), sabemos que no todas las celdas del rango están en blanco. Si la prueba lógica es FALSA, eso significa que todas las celdas del rango están en blanco. Por lo tanto, proporcionamos el valor/expresión/fórmula deseado en el tercer argumento de IF (value_if_false).
En este ejemplo, devolveremos «No iniciado» para los proyectos que tienen espacios en blanco para todos los hitos en las columnas B a D.
La forma más fácil de contar celdas no vacías en Excel es usando la función CONTAR:
=IF(COUNTA(B2:D2)>0, "", "Not Started")
Otra forma es CONTAR.SI para no espacios en blanco («<>» como criterio):
=IF(COUNTIF(B2:D2,"<>")>0, "", "Not Started")
O la función SUMPRODUCT con la misma lógica:
=IF(SUMPRODUCT(--(B2:D2<>""))>0, "", "Not Started")
ISBLANK también se puede usar, pero solo como una fórmula de matriz, que debe completarse presionando Ctrl + Shift + Enter, y en combinación con la función AND. AND es necesario para que la prueba lógica se evalúe como VERDADERO solo cuando el resultado de ESBLANCO para cada celda es VERDADERO.
=IF(AND(ISBLANK(B2:D2)), "Not Started", "")
Nota. Al elegir una fórmula para su hoja de trabajo, una cosa importante a considerar es su comprensión de los «espacios en blanco». Las fórmulas basadas en ISBLANK, COUNTA y COUNTIF con «<>» como criterio buscan celdas absolutamente vacías. SUMPRODUCT también considera las cadenas vacías como espacios en blanco.
Fórmula de Excel: si la celda no está en blanco, entonces suma
Para sumar ciertas celdas cuando otras celdas no están en blanco, use la función SUMAR.SI, que está especialmente diseñada para la suma condicional.
En la siguiente tabla, suponga que desea encontrar el monto total de los artículos que ya se entregaron y los que aún no se entregaron.
Si no está en blanco, suma
Para obtener el total de artículos entregados, verifique si la Fecha de entrega en la columna B no está en blanco y, si no lo está, sume el valor en la columna C:
=SUMIF(B2:B6, "<>", C2:C6)
Si está en blanco entonces suma
Para obtener el total de artículos no entregados, sume si la Fecha de entrega en la columna B está en blanco:
=SUMIF(B2:B6, "", C2:C6)
Suma si todas las celdas en el rango no están en blanco
Para sumar celdas o realizar algún otro cálculo solo cuando todas las celdas en un rango dado no están en blanco, puede usar nuevamente la función IF con la prueba lógica apropiada.
Por ejemplo, COUNTBLANK puede traernos el número total de espacios en blanco en el rango B2:B6. Si el conteo es cero, ejecutamos la fórmula SUM; de lo contrario no hagas nada:
=IF(COUNTBLANK(B2:B6)=0, SUM(B2:B6), "")
El mismo resultado se puede lograr con un formación Fórmula IF ISBLANK SUM (recuerde presionar Ctrl + Shift + Enter para completarla correctamente):
=IF(OR(ISBLANK(B2:B6)), "", SUM(B2:B6))
En este caso, usamos ISBLANK en combinación con la función OR, por lo que la prueba lógica es VERDADERA si hay al menos una celda en blanco en el rango. En consecuencia, la función SUMA va al argumento valor_si_falso.
Fórmula de Excel: cuente si la celda no está en blanco
Como probablemente sepa, Excel tiene una función especial para contar celdas que no están vacías, la función COUNTA. Tenga en cuenta que la función cuenta las celdas que contienen cualquier tipo de datos, incluidos los valores lógicos de VERDADERO y FALSO, error, espacios, cadenas vacías, etc.
Por ejemplo, para contar no en blanco celdas en el rango B2:B6, esta es la fórmula a usar:
=COUNTA(B2:B6)
Se puede lograr el mismo resultado usando COUNTIF con los criterios que no están en blanco («<>«):
=COUNTIF(B2:B6,"<>")
Para contar vacío celdas, use la función COUNTBLANK:
=COUNTBLANK(B2:B6)
Excel ISBLANK no funciona
Como ya se mencionó, ISBLANK en Excel devuelve VERDADERO solo para celdas realmente vacías que no contienen absolutamente nada. Para celdas aparentemente en blanco que contiene fórmulas que producen cadenas vacías, espacios, apóstrofes, caracteres no imprimibles y similares, ESBLANCO devuelve FALSO.
En una situación en la que desee tratar las celdas visualmente vacías como espacios en blanco, considere las siguientes soluciones alternativas.
Tratar cadenas de longitud cero como espacios en blanco
Para considerar las celdas con cadenas de longitud cero como espacios en blanco, en la prueba lógica de IF, ponga una cadena vacía («») o la función LEN igual a cero.
=IF(A2="", "blank", "not blank")
O
=IF(LEN(A2)=0, "blank", "not blank")
Eliminar o ignorar espacios adicionales
En caso de que la función ISBLANK no funcione correctamente debido a los espacios en blanco, la solución más obvia es deshacerse de ellos. El siguiente tutorial explica cómo eliminar rápidamente los espacios iniciales, finales y múltiples espacios intermedios, a excepción de un solo carácter de espacio entre palabras: Cómo eliminar espacios adicionales en Excel.
Si por alguna razón eliminar los espacios en exceso no funciona para usted, puede obligar a Excel a ignorarlos.
Para considerar las celdas que contienen solo caracteres de espacio como vacío, incluya LEN(TRIM(cell))=0 en la prueba lógica de IF como condición adicional:
=IF(OR(A2="", LEN(TRIM(A2))=0), "blank", "not blank")
para ignorar un carácter no imprimible específicoencuentre su código y proporciónelo a la función CHAR.
Por ejemplo, para identificar las celdas que contienen cadenas vacías y espacios que no se rompen ( ) como espacios en blanco, use la siguiente fórmula, donde 160 es el código de carácter para un espacio de no separación:
=IF(OR(A2="", A2=CHAR(160)), "blank", "not blank")
Así es como se usa la función ESBLANCO para identificar celdas en blanco en Excel. ¡Gracias por leer y espero verte en nuestro blog la próxima semana!