El tutorial muestra cómo combinar BUSCARV y la función IF juntas para buscar v con la condición if en Excel. También aprenderá a usar fórmulas IF ISNA VLOOKUP para reemplazar errores #N/A con su propio texto, cero o celda en blanco.
Si bien las funciones BUSCARV e IF son útiles por sí solas, juntas brindan experiencias aún más valiosas. Este tutorial implica que recuerda bien la sintaxis de las dos funciones; de lo contrario, es posible que desee repasar sus conocimientos siguiendo los enlaces anteriores.
Vlookup con instrucción If: devuelve verdadero/falso, sí/no, etc.
Uno de los escenarios más comunes cuando combina If y Vlookup juntos es comparar el valor devuelto por Vlookup con un valor de muestra y devolver Sí/No o Verdadero/Falso como resultado.
En la mayoría de los casos, la siguiente fórmula genérica funcionaría bien:
SI(BUSCARV(…) = valor, VERDADERO, FALSO)
Traducido en lenguaje sencillo, la fórmula le indica a Excel que devuelva True si Vlookup es verdadero (es decir, igual al valor especificado). Si Vlookup es falso (no es igual al valor especificado), la fórmula devuelve Falso.
A continuación, encontrará algunos usos de la vida real de esta fórmula IF Vlookup.
Ejemplo 1. Buscar un valor específico
Supongamos que tiene una lista de artículos en la columna A y una cantidad en la columna B. Está creando un tablero para sus usuarios y necesita una fórmula que verifique la cantidad de un artículo en E1 e informe al usuario si el artículo está en stock. o agotado.
Obtienes la cantidad con un Vlookup regular con una fórmula de coincidencia exacta como esta:
=VLOOKUP(E1,$A$2:$B$10,2,FALSE)
Luego, escriba una declaración IF que compare el resultado de Vlookup con cero y devuelva «No» si es igual a 0, «Sí» de lo contrario:
=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")
En lugar de Sí/No, puede devolver VERDADERO/FALSO o Disponible/Agotado o cualquier otra opción. Por ejemplo:
=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")
También puede comparar el valor devuelto por Vlookup con la muestra texto. En este caso, asegúrese de encerrar una cadena de texto entre comillas, como esta:
=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)
Ejemplo 2. Compara el resultado de Vlookup con otra celda
Otro ejemplo típico de Vlookup con la condición If en Excel es comparar la salida de Vlookup con un valor en otra celda. Por ejemplo, podemos verificar si es mayor o igual que un número en la celda G2:
=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")
Y aquí está nuestra fórmula If con Vlookup en acción:
De manera similar, puede usar cualquier otro operador lógico junto con una referencia de celda en su fórmula Excel If Vlookup.
Ejemplo 3. Valores de Vlookup en una lista más corta
Para comparar cada celda en la columna de destino con otra lista y devolver Verdadero o Sí si se encuentra una coincidencia, Falso o No de lo contrario, use esta fórmula genérica IF ISNA VLOOKUP:
SI(ESNA(BUSCARV(…)),»No»,»Sí»)
Si Vlookup da como resultado el error #N/A, la fórmula devuelve «No», lo que significa que el valor de búsqueda no se encuentra en la lista de búsqueda. Si se encuentra la coincidencia, se devuelve «Sí». Por ejemplo:
=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")
Si su lógica comercial requiere los resultados opuestos, simplemente cambie «Sí» y «No» para invertir la lógica de la fórmula:
=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")
Fórmula Excel If Vlookup para realizar diferentes cálculos
Además de mostrar sus propios mensajes de texto, la función If con Vlookup puede realizar diferentes cálculos según los criterios que especifique.
Tomando nuestro ejemplo más allá, calculemos la comisión de un vendedor específico (F1) dependiendo de su efectividad: 20% de comisión para aquellos que ganaron $200 o más, 10% para todos los demás.
Para ello compruebas si el valor devuelto por Vlookup es mayor o igual a 200, y si lo es lo multiplicas por 20%, en caso contrario por 10%:
=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)
Donde A2:A10 son nombres de vendedores y C2:C10 son ventas.
IF ISNA VLOOKUP para ocultar errores #N/A
Si la función BUSCARV no puede encontrar un valor específico, arroja un error #N/A. Para detectar ese error y reemplazarlo con su propio texto, incruste una fórmula Vlookup en la prueba lógica de la función IF, como esta:
IF(ISNA(BUSCARV(…)), «No encontrado», BUSCARV(…))
Naturalmente, puede escribir cualquier texto que desee en lugar de «No encontrado».
Supongamos que tiene una lista de nombres de vendedores en una columna y montos de ventas en otra columna. Su tarea es sacar un número correspondiente al nombre que el usuario ingresa en F1. Si no se encuentra el nombre, mostrar un mensaje indicándolo.
Con los nombres en A2:A10 y las cantidades C2:C10, la tarea se puede realizar con la siguiente fórmula If Vlookup:
=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))
Si se encuentra el nombre, se devuelve el importe de venta correspondiente:
Si no se encuentra el valor de búsqueda, aparece el mensaje No encontrado en lugar del error #N/A:
Cómo funciona esta fórmula
La lógica de la fórmula es muy simple: usa la función ISNA para verificar si Vlookup tiene errores #N/A. Si ocurre un error, ISNA devuelve VERDADERO, de lo contrario FALSO. Los valores anteriores van a la prueba lógica de la función IF, que realiza una de las siguientes acciones:
- Si la prueba lógica es VERDADERA (error #N/A), se muestra su mensaje.
- Si la prueba lógica es FALSA (se encuentra el valor de búsqueda), Vlookup devuelve una coincidencia normalmente.
IFNA VLOOKUP en versiones más recientes de Excel
A partir de Excel 2013, puede usar la función IFNA en lugar de IF ISNA para detectar y manejar errores #N/A:
IFNA(BUSCARV(…), «No encontrado»)
En nuestro ejemplo, la fórmula tomaría la siguiente forma:
=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")
Consejo. Si desea detectar todo tipo de errores, no solo #N/A, use BUSCARV en combinación con la función IFERROR. Puede encontrar más detalles aquí: IFERROR VLOOKUP en Excel.
Excel Vlookup: si no se encuentra, devuelve 0
Cuando trabaje con valores numéricos, es posible que desee devolver un cero cuando no se encuentre el valor de búsqueda. Para hacerlo, use la fórmula IF ISNA VLOOKUP discutida anteriormente con una pequeña modificación: en lugar de un mensaje de texto, proporcione 0 en el argumento value_if_true de la función IF:
SI(ESNA(BUSCARV(…)), 0, BUSCARV(…))
En nuestra tabla de ejemplo, la fórmula sería la siguiente:
=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))
En las versiones recientes de Excel 2016 y 2013, puede volver a utilizar la combinación IFNA Vlookup:
=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)
Excel Vlookup: si no se encuentra, devuelve una celda en blanco
Esta es una variación más de la declaración «Vlookup if then»: no devuelve nada cuando no se encuentra el valor de búsqueda. Para hacer esto, indique a su fórmula que devuelva una cadena vacía («») en lugar del error #N/A:
SI(ESNA(BUSCARV(…)), «», BUSCARV(…))
A continuación hay un par de ejemplos completos de fórmulas:
Para todas las versiones de Excel:
=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))
Para Excel 2016 y Excel 2013:
=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")
Si con coincidencia de índice: vlookup izquierdo con condición If
Los usuarios experimentados de Excel saben que la función BUSCARV no es la única forma de realizar búsquedas verticales en Excel. La combinación INDEX MATCH también se puede utilizar para este propósito y es aún más potente y versátil. La buena noticia es que Index Match puede funcionar junto con IF exactamente de la misma manera que Vlookup.
Por ejemplo, tiene números de pedido en la columna A y nombres de vendedores en la columna B. Está buscando una fórmula para obtener el número de pedido de un vendedor específico.
Vlookup no se puede usar en este caso porque no puede buscar de derecha a izquierda. Index Match funcionará sin problemas siempre que el valor de búsqueda se encuentre en la columna de búsqueda. De lo contrario, aparecerá un error #N/A. Para reemplazar la notación de error estándar con su propio texto, anide Index Match dentro de IF ISNA:
=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))
En Excel 2016 y 2016, puede usar IFNA en lugar de IF ISNA para hacer la fórmula más compacta:
=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")
De manera similar, puede usar Index Match en otras fórmulas If.
Así es como usa Vlookup y la declaración IF juntas en Excel. Para ver más de cerca las fórmulas discutidas en este tutorial, puede descargar nuestro libro de trabajo de muestra a continuación. ¡Gracias por leer y espero verte en nuestro blog la próxima semana!
(archivo .xlsx)