El tutorial analiza la sintaxis y los usos básicos de la función COUNTBLANK para contar el número de celdas en blanco en Excel.
En un par de publicaciones recientes, hemos discutido diferentes formas de identificar celdas en blanco y resaltar espacios en blanco en Excel. En algunas situaciones, sin embargo, es posible que desee saber cuántas celdas no tienen nada en ellas. Microsoft Excel también tiene una función especial para esto. Este tutorial le mostrará los métodos más rápidos y convenientes para obtener la cantidad de celdas vacías en un rango, así como filas totalmente en blanco.
Función CONTARBLANCOS de Excel
La función COUNTBLANK en Excel está diseñada para contar celdas vacías en un rango específico. Pertenece a la categoría de Funciones estadísticas y está disponible en todas las versiones de Excel para Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 y Excel 2007.
La sintaxis de esta función es muy sencilla y requiere solo un argumento:
CONTARBLANCO(rango)
Donde rango es el rango de celdas en las que se van a contar los espacios en blanco.
Aquí hay un ejemplo de la fórmula COUNTBLANK en Excel en su forma más simple:
=COUNTBLANK(A2:D2)
La fórmula, ingresada en E2 y copiada hasta E7, determina el número de celdas vacías en las columnas A a D en cada fila y devuelve estos resultados:
Consejo. Para contar no en blanco celdas en Excel, use la función COUNTA.
Función COUNTBLANK – 3 cosas para recordar
Para usar efectivamente una fórmula de Excel para contar celdas en blanco, es importante comprender qué celdas considera la función COUNTBLANK como «espacios en blanco».
- No se cuentan las celdas que contienen texto, números, fechas, valores lógicos, espacios o errores.
- Células que contienen ceros se consideran no en blanco y no se cuentan.
- Celdas que contienen fórmulas que devuelven cadenas vacías («») se consideran en blanco y se cuentan.
Mirando la captura de pantalla anterior, tenga en cuenta que la celda A7 que contiene una fórmula que devuelve una cadena vacía se cuenta dos veces:
- COUNTBLANK considera una cadena de longitud cero como una celda vacía porque aparece en blanco.
- CONTARA trata una cadena de longitud cero como una celda no vacía porque en realidad contiene una fórmula.
Eso puede sonar un poco ilógico, pero Excel funciona de esta manera 🙂
Cómo contar celdas en blanco en Excel – ejemplos de fórmulas
COUNTBLANK es la forma más conveniente, pero no la única, de contar celdas vacías en Excel. Los siguientes ejemplos demuestran algunos otros métodos y explican qué fórmula es mejor usar en qué escenario.
Cuente las celdas en blanco en el rango con COUNTBLANK
Siempre que necesite contar espacios en blanco en Excel, COUNTBLANK es la primera función que debe probar.
Por ejemplo, para obtener el número de celdas vacías en cada fila de la siguiente tabla, ingresamos la siguiente fórmula en F2:
=COUNTBLANK(A2:E2)
Como usamos referencias relativas para el rango, podemos simplemente arrastrar la fórmula hacia abajo y las referencias se ajustarán automáticamente para cada fila, produciendo el siguiente resultado:
Cómo contar celdas en blanco en Excel usando COUNTIFS o COUNTIF
Otra forma de contar celdas vacías en Excel es usar la función CONTAR.SI o CONTAR.SI o con una cadena vacía («») como criterio.
En nuestro caso, las fórmulas irían de la siguiente manera:
=COUNTIF(B2:E2, "")
O
=COUNTIFS(B2:E2, "")
Como puede ver en la captura de pantalla a continuación, los resultados de COUNTIFS son exactamente los mismos que los de COUNTBLANK, por lo que la fórmula a usar en este escenario es una cuestión de preferencia personal.
Contar celdas en blanco con condición
En una situación, cuando desea contar celdas vacías en función de alguna condición, COUNTIFS es la función correcta para usar ya que su sintaxis proporciona múltiples criterios.
Por ejemplo, para determinar la cantidad de celdas que tienen «Manzanas» en la columna A y espacios en blanco en la columna C, use esta fórmula:
=COUNTIFS(A2:A9, "apples", C2:C9, "")
O ingrese la condición en una celda predefinida, digamos F1, y haga referencia a esa celda como el criterio:
=COUNTIFS(A2:A9, F1, C2:C9, "")
SI CUENTABLANCOS en Excel
En algunos casos, es posible que no solo necesite contar las celdas en blanco en un rango, sino tomar alguna acción dependiendo de si hay celdas vacías o no.
Aunque no hay una función IF COUNTBLANK incorporada en Excel, puede crear fácilmente su propia fórmula usando las funciones IF y COUNTBLANK juntas. Así es cómo:
- Comprueba si el recuento de espacios en blanco es igual a cero y pon esta expresión en la prueba lógica de SI:
COUNTBLANK(B2:D2)=0 - Si la prueba lógica se evalúa como VERDADERO, emite «Sin espacios en blanco».
- Si la prueba lógica se evalúa como FALSO, genera «Vacíos».
La fórmula completa toma esta forma:
=IF(COUNTBLANK(B2:D2)=0, "No blanks", "Blanks")
Como resultado, la fórmula identifica todas las filas en las que faltan uno o más valores:
O puede ejecutar otra función dependiendo del recuento de espacios en blanco. Por ejemplo, si no hay celdas vacías en el rango B2:D2 (es decir, si COUNTBLANK devuelve 0), sume los valores, de lo contrario devuelva «Vacíos»:
=IF(COUNTBLANK(B2:D2)=0, SUM(B2:D2), "Blanks")
Cómo contar filas en blanco en Excel
Supongamos que tiene una tabla en la que algunas filas contienen información mientras que otras filas están totalmente en blanco. La pregunta es: ¿cómo se obtiene el número de filas que no contienen nada?
La solución más fácil que se me ocurre es agregar una columna de ayuda y llenarla con la fórmula COUNTBLANK de Excel que encuentra la cantidad de celdas en blanco en cada fila:
=COUNTBLANK(A2:E2)
Y luego, use la función CONTAR.SI para averiguar en cuántas filas todas las celdas están en blanco. Dado que nuestra tabla de origen contiene 5 columnas (A a E), contamos las filas que tienen 5 celdas vacías:
=COUNTIF(F2:F8, 5))
En lugar de «codificar» el número de columnas, puede usar la función COLUMNAS para calcularlo automáticamente:
=COUNTIF(F2:F8, COLUMNS(A2:E2))
Si no desea alterar la estructura de su hoja de trabajo bellamente diseñada, puede lograr el mismo resultado con una fórmula mucho más compleja que, sin embargo, no requiere ninguna columna de ayuda ni siquiera el ingreso de matrices:
=SUM(--(MMULT(--(A2:E8<>""), ROW(INDIRECT("A1:A"&COLUMNS(A2:E8))))=0))
Trabajando de adentro hacia afuera, esto es lo que hace la fórmula:
- Primero, verifica todo el rango en busca de celdas que no estén en blanco usando la expresión como A2:E8<>«», y luego coacciona los valores lógicos devueltos de VERDADERO y FALSO a 1 y 0 usando el operador unario doble (–) . El resultado de esta operación es una matriz bidimensional de unos (no espacios en blanco) y ceros (espacios en blanco).
- El propósito de la parte ROW es generar una matriz vertical de valores numéricos. distinto de cero valores, en los que el número de elementos es igual al número de columnas del rango. En nuestro caso, el rango consta de 5 columnas (A2:E8), por lo que obtenemos esta matriz: {1;2;3;4;5}
- La función MMULT calcula el producto matricial de las matrices anteriores y produce un resultado como: {11;0;15;8;0;8;10}. En esta matriz, lo único que nos importa son los valores 0 que representan las filas donde todas las celdas están en blanco.
- Finalmente, compara cada elemento de la matriz anterior con cero, obliga a VERDADERO y FALSO a 1 y 0, y luego suma los elementos de esta matriz final: {0;1;0;0;1;0;0}. Teniendo en cuenta que los 1 corresponden a filas en blanco, obtienes el resultado deseado.
Si la fórmula anterior le parece demasiado difícil de comprender, es posible que le guste más esta:
=SUM(--(COUNTIF(INDIRECT("A"&ROW(A2:A8) & ":E"&ROW(A2:A8)), "<>"&"")=0))
Aquí, utiliza la función COUNTIF para encontrar cuántas celdas que no están en blanco hay en cada fila, e INDIRECTO «alimenta» las filas a COUNTIF una por una. El resultado de esta operación es una matriz como {4;0;5;3;0;3;4}. Una verificación de 0 transforma la matriz anterior en {0;1;0;0;1;0;0} donde los 1 representan filas en blanco, por lo que solo necesita sumarlas.
Cuente celdas verdaderamente en blanco excluyendo cadenas vacías
En todos los ejemplos anteriores, contábamos celdas en blanco, incluidas aquellas que solo aparecen en blanco pero, en realidad, contienen cadenas vacías («») devueltas por algunas fórmulas. En caso de que desee excluir cadenas de longitud cero del resultado, puede usar esta fórmula genérica:
FILAS (rango) * COLUMNAS (rango) – COUNTA (rango)
Lo que hace la fórmula es multiplicar el número de filas por el número de columnas para obtener el total de celdas en el rango, del cual se resta el número de no espacios en blanco devuelto por COUNTA. Como recordará, la función CONTARA de Excel considera las cadenas vacías como celdas que no están en blanco, por lo que no se incluirán en el resultado final.
Por ejemplo, para determinar cuántas celdas absolutamente vacías hay en el rango A2:A8, esta es la fórmula que debe usar:
=ROWS(A2:A8) * COLUMNS(A2:A8) - COUNTA(A2:A8)
La siguiente captura de pantalla muestra el resultado:
Así es como se cuentan las celdas vacías en Excel. ¡Gracias por leer y espero verte en nuestro blog la próxima semana!