El tutorial analiza cómo aprovechar las nuevas funciones de matriz dinámica para contar valores únicos en Excel: fórmula para contar entradas únicas en una columna, con múltiples criterios, ignorando espacios en blanco y más.
Hace un par de años, discutimos varias formas de contar valores únicos y distintos en Excel. Pero como cualquier otro programa de software, Microsoft Excel evoluciona continuamente y aparecen nuevas funciones en casi todas las versiones. Hoy, veremos cómo se puede contar valores únicos en Excel con las funciones de matriz dinámica introducidas recientemente. Si aún no ha utilizado ninguna de estas funciones, se sorprenderá al ver cuánto más simples se vuelven las fórmulas en términos de construcción y comodidad de uso.
Nota. Todas las fórmulas analizadas en este tutorial se basan en la función ÚNICA, que solo está disponible en Excel 365 y Excel 2021. Si está utilizando Excel 2019, Excel 2016 o versiones anteriores, consulte este artículo para obtener soluciones.
Contar valores únicos en la columna
La forma más fácil de contar valores únicos en una columna es usar la función ÚNICO junto con la función CONTARA:
CONTARA(ÚNICO(rango))
La fórmula funciona con esta lógica simple: ÚNICO devuelve una matriz de entradas únicas y CONTARA cuenta todos los elementos de la matriz.
Como ejemplo, contemos nombres únicos en el rango B2:B10:
=COUNTA(UNIQUE(B2:B10))
La fórmula nos dice que hay 5 nombres diferentes en la lista de ganadores:
Consejo. En este ejemplo, contamos valores de texto únicos, pero también puede usar esta fórmula para otros tipos de datos, incluidos números, fechas, horas, etc.
Cuente los valores únicos que ocurren solo una vez
En el ejemplo anterior, contamos todas las entradas diferentes (distintas) en una columna. Esta vez, queremos saber el número de registros únicos que ocurrir solo una vez. Para hacerlo, construye tu fórmula de esta manera:
Para obtener una lista de ocurrencias únicas, establezca el tercer argumento de ÚNICO en VERDADERO:
UNIQUE(B2:B10,,TRUE))
Para contar las ocurrencias únicas únicas, anide ÚNICO en la función FILA:
ROWS(UNIQUE(B2:B10,,TRUE))
Tenga en cuenta que COUNTA no funcionará en este caso porque cuenta todas las celdas que no están en blanco, incluidos los valores de error. Entonces, si no se encuentran resultados, UNIQUE devolverá un error y COUNTA lo contará como 1, ¡lo cual es incorrecto!
Para manejar posibles errores, ajuste la función IFERROR alrededor de su fórmula e indíquele que genere 0 si ocurre algún error:
=IFERROR(ROWS(UNIQUE(B2:B10,,TRUE)), 0)
Como resultado, obtiene un conteo basado en el concepto de base de datos de único:
Contar filas únicas en Excel
Ahora que sabe cómo contar celdas únicas en una columna, ¿alguna idea sobre cómo encontrar la cantidad de filas únicas?
Aquí está la solución:
FILAS (ÚNICO (rango))
El truco es «alimentar» todo el rango a ÚNICO para que encuentre las combinaciones únicas de valores en varias columnas. Después de eso, simplemente encierre la fórmula en la función FILAS para calcular el número de filas.
Por ejemplo, para contar las filas únicas en el rango A2:C10, usamos esta fórmula:
=ROWS(UNIQUE(A2:C10))
Contar entradas únicas ignorando celdas en blanco
Para contar valores únicos en Excel ignorando los espacios en blanco, utilice la función FILTRO para filtrar las celdas vacías y luego distorsionarlo en la ya familiar fórmula CONTAR UN ÚNICO:
CONTARA(ÚNICO(FILTRO(rango, rango<>«»)))
Con los datos de origen en B2:B11, la fórmula toma esta forma:
=COUNTA(UNIQUE(FILTER(B2:B11, B2:B11<>"")))
La siguiente captura de pantalla muestra el resultado:
Contar valores únicos con criterios
Para extraer valores únicos en función de ciertos criterios, vuelva a utilizar las funciones ÚNICO y FILTRO juntas como se explica en este ejemplo. Y luego, usa la función ROWS para contar entradas únicas y IFERROR para atrapar todo tipo de errores y reemplazarlos con 0:
SI.ERROR(FILAS(ÚNICO(rango, criterio_rango=criterio))), 0)
Por ejemplo, para encontrar cuántos ganadores diferentes hay en un deporte específico, use esta fórmula:
=IFERROR(ROWS(UNIQUE(FILTER(A2:A10,B2:B10=E1))), 0)
Donde A2:A10 es un rango para buscar nombres únicos (rango), B2:B10 son los deportes en los que compiten los ganadores (criterios_rango) y E1 es el deporte de interés (criterios).
Contar valores únicos con múltiples criterios
La fórmula para contar valores únicos en función de múltiples criterios es bastante similar al ejemplo anterior, aunque los criterios se construyen de manera un poco diferente:
SI.ERROR(FILAS(ÚNICO(rango, (criterios_rango1=criterios1) * (criterios_rango2=criterios2)))), 0)
Aquellos que tengan curiosidad por conocer la mecánica interna, pueden encontrar la explicación de la lógica de la fórmula aquí: Encuentra valores únicos basados en múltiples criterios.
En este ejemplo, vamos a averiguar cuántos ganadores diferentes hay en un deporte específico en F1 (criterio 1) y menores de edad en F2 (criterio 2). Para ello, estamos utilizando esta fórmula:
=IFERROR(ROWS(UNIQUE(FILTER(A2:A10, (B2:B10=F1) * (C2:C10<F2)))), 0)
Donde A2:B10 es la lista de nombres (rango), C2:C10 son deportes (criterio_rango 1) y D2:D10 son edades (criterio_rango 2).
Así es como contar valores únicos en Excel con las nuevas funciones de matriz dinámica. Estoy seguro de que aprecia cuánto más simples se vuelven todas las soluciones. De todos modos, ¡gracias por leer y esperamos verte en nuestro blog la próxima semana!
Cuaderno de ejercicios para descargar
(archivo .xlsx)