El tutorial analiza cómo usar las funciones ISTEXT y ISNONTEXT en Excel para verificar si una celda contiene un valor textual o no.
Siempre que necesite obtener información sobre el contenido de alguna celda en Excel, normalmente usaría las llamadas funciones de información. Tanto ISTEXT como ISNONTEXT pertenecen a esta categoría. La función ISTEXT comprueba si un valor es texto y ISNONTEXT comprueba si un valor no es texto. Cualquiera que sea el concepto simple, las funciones son increíblemente útiles para resolver una variedad de tareas diferentes en Excel.
Función Excel ISTEXT
La función ISTEXT en las comprobaciones de Excel es un valor especificado, sea texto o no. Si el valor es textual, la función devuelve VERDADERO. Para todos los demás tipos de datos (como números, fechas, celdas en blanco, errores, etc.) devuelve FALSO.
La sintaxis es la siguiente:
ISTEXT(value)
Donde valor es un valor, referencia de celda, expresión u otra función cuyo resultado desea probar.
Por ejemplo, para averiguar si un valor en A2 es texto o no, utilice esta sencilla fórmula:
=ISTEXT(A2)
Función Excel ESNOTEXTO
La función ESNOTEXTO devuelve VERDADERO para cualquier valor que no sea de texto, incluidos números, fechas y horas, espacios en blanco y otras fórmulas que devuelvan resultados o errores no textuales. Para valores de texto, devuelve FALSO.
La sintaxis es la misma que la de la función ISTEXT:
ISTEXT(value)
Por ejemplo, para verificar si un valor en A2 no es texto, use esta fórmula:
=ISNONTEXT(A2)
Como se muestra en la siguiente captura de pantalla, las fórmulas ISTEXT y ISNONTEXT devuelven los resultados opuestos:
Funciones ISTEXT y ISNONTEXT en Excel – notas de uso
ISTEXT e ISNONTEXT son funciones muy sencillas y fáciles de usar, y es poco probable que tenga dificultades con ellas. Dicho esto, hay algunos puntos clave a tener en cuenta:
- Ambas funciones forman parte del grupo de funciones IS que devuelven los valores lógicos (booleanos) de VERDADERO o FALSO.
- En un caso específico cuando los números se almacenan como textoISTEXT devuelve VERDADERO y ISNONTEXT devuelve FALSO.
- Ambas funciones están disponibles en todas las versiones de Excel para Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007, Excel 2003, Excel XP y Excel 2000.
Uso de ISTEXT y ISNONTEXT en Excel: ejemplos de fórmulas
A continuación, encontrará ejemplos de usos prácticos de las funciones ISTEXT y ISNONTEXT en Excel que, con suerte, lo ayudarán a hacer que sus hojas de trabajo sean más eficientes.
Comprobar si un valor es texto
A veces, cuando está trabajando con un montón de valores, puede sorprenderse al notar que para algunos números sus fórmulas arrojan resultados incorrectos o incluso errores. La razón más obvia es que los números problemáticos se almacenan como texto. Las siguientes fórmulas le dirán con certeza qué valores son texto desde el punto de vista de Excel.
Fórmula ISTEXT:
Devuelve VERDADERO para cualquier valor que Excel considere texto.
=ISTEXT(B2)
Fórmula ESNOTEXTO:
Devuelve VERDADERO para cualquier valor que Excel considere sin texto.
=ISNONTEXT(B2)
ISTEXT para validación de datos: permite solo texto
En algunas situaciones, es posible que desee permitir que los usuarios ingresen solo valores de texto en ciertas celdas. Para lograr esto, cree una regla de validación de datos basada en una fórmula ISTEXT. Así es cómo:
- Seleccione una o más celdas que desee validar.
- En la pestaña Datos, en el grupo Herramientas de datos, haga clic en el Validación de datos botón.
- En la pestaña Configuración del cuadro de diálogo Validación de datos, seleccione Disfraz para los criterios de validación e ingrese su fórmula ISTEXT en el cuadro correspondiente.
- Haga clic en Aceptar para guardar la regla.
Para este ejemplo, estamos validando las respuestas del cuestionario en las celdas B2 a B4 con la ayuda de esta fórmula:
=ISTEXT(B2:B4)
Además, puede configurar su propio mensaje de alerta de error para explicar a sus usuarios qué tipo de datos se aceptan:
Como resultado, cuando el usuario intente ingresar un número o fecha en cualquiera de las celdas validadas, verá la siguiente alerta:
Para obtener más información, consulte Uso de la validación de datos en Excel.
Fórmula de Excel IF ISTEXT
En la práctica, ISTEXT y ISNONTEXT a menudo se usan junto con la función IF para generar un resultado más fácil de usar que el estándar VERDADERO y FALSO.
Fórmula 1. Si es texto, entonces
Tomando nuestro primer ejemplo un poco más allá, supongamos que desea devolver «Sí» para valores de texto y «No» para cualquier otra cosa. Para hacerlo, simplemente anide la función ISTEXT en la prueba lógica de IF y use «Sí» y «No» para los argumentos valor_si_verdadero y valor_si_falso, respectivamente:
=IF(ISTEXT(A2), "Yes", "No")
Fórmula 2. Verifique la entrada de la celda
En uno de los ejemplos anteriores, discutimos cómo garantizar una entrada de usuario válida mediante la Validación de datos. Esto también se puede hacer en una forma «más suave» con la ayuda de una fórmula Excel IF ISTEXT.
En el cuestionario, suponga que desea determinar qué respuestas son válidas (texto) y cuáles no (no texto). Para esto, use las declaraciones IF anidadas con la siguiente lógica:
- Si la celda probada está vacía, no devuelve nada, es decir, una cadena vacía («»).
- Si la celda es texto, devuelve «Respuesta válida».
- Si no cumple con ninguno de los anteriores, devuelva «Respuesta no válida: ingrese el texto».
Al juntar todo esto, obtenemos la siguiente fórmula, donde B2 es la celda a verificar:
=IF(B2="", "", IF(ISTEXT(B2), "Valid answer", "Invalid answer - please enter text."))
Comprobar si un rango contiene algún texto
Hasta ahora, hemos probado cada celda individualmente. Pero, ¿qué sucede si necesita saber si alguna celda de un rango contiene texto?
Para probar todo el rango, combine la función ISTEXT con SUMPRODUCT de esta manera:
SUMAPRODUCTO(ESTEXTO(rango)*1)>0
SUMAPRODUCTO(–ISTEXT(rango))>0
Como ejemplo, revisemos cada fila en el siguiente conjunto de datos para valores de texto, lo que se puede hacer con las siguientes fórmulas:
=SUMPRODUCT(ISTEXT(A2:C2)*1)>0
=SUMPRODUCT(--ISTEXT(A2:C2))>0
Una de las fórmulas anteriores va a la celda D2 y luego la arrastra hacia abajo a través de la celda D5.
Entonces, ahora tiene una comprensión clara de qué filas contienen una o más cadenas de texto (VERDADERO) y cuáles contienen solo números (FALSO).
Si desea obtener resultados diferentes, diga «Sí» o «No» en lugar de VERDADERO y FALSO, incluya la fórmula anterior en la instrucción IF:
=IF(SUMPRODUCT(--ISTEXT(A2:C2))>0, "Yes", "No")
Cómo funciona esta fórmula
La fórmula se basa en la capacidad de SUMPRODUCT para manejar matrices de forma nativa. Trabajando de adentro hacia afuera, esto es lo que hace:
- La función ISTEXT devuelve una matriz de valores VERDADERO y FALSO. Para A2:C2, obtenemos esta matriz:
{TRUE,TRUE,FALSE} - A continuación, multiplicamos cada elemento de la matriz anterior por 1 para convertir los valores lógicos de VERDADERO y FALSO en 1 y 0, respectivamente. Se puede utilizar un operador unario doble (–) para el mismo propósito. Después de la transformación, la fórmula toma esta forma:
SUMPRODUCT({1,1,0})>0 - La función SUMPRODUCT suma 1 y 0, y verifica si el resultado es mayor que cero. Si es así, el rango contiene al menos un valor de texto y la fórmula devuelve VERDADERO, si no FALSO.
Comprobar si una celda contiene un texto específico
La función ISTEXT de Excel solo puede determinar si una celda contiene texto, es decir, absolutamente cualquier texto. Para averiguar si una celda contiene una cadena de texto específica, use la fórmula BÚSQUEDA DE ESNÚMERO o CONTAR.SI con comodines.
Por ejemplo, para ver si el Id. de artículo en A2 contiene la cadena de texto ingresada en la celda D2, use la siguiente fórmula (tenga en cuenta la referencia absoluta $D$2 que evita que la dirección de la celda cambie cuando la fórmula se copia en otras celdas):
=ISNUMBER(SEARCH($D$2, A2))
Por conveniencia, lo incluiremos en la función IF:
=IF(ISNUMBER(SEARCH($D$2, A2)), "Yes", "No")
Y obtener los siguientes resultados:
El mismo resultado se puede lograr con COUNTIF:
=IF(COUNTIF(A2, "*"&$D$2&"*")>0, "Yes", "No")
Para obtener más ejemplos, consulte Excel si la celda contiene fórmulas.
Resaltar celdas que contienen texto
La función ISTEXT también se puede usar con formato condicional de Excel para resaltar celdas que contienen valores de texto. Así es cómo:
- Seleccione todas las celdas que desea verificar y resalte (A2: C5 en este ejemplo).
- En la pestaña Inicio, en el grupo Estilos, haga clic en Nueva regla > Usar una fórmula para determinar a qué celdas dar formato.
- En el cuadro Formatear valores donde esta fórmula es verdadera, ingrese la siguiente fórmula:
=ISTEXT(A2)Donde A2 es la celda más a la izquierda del rango seleccionado.
- Haga clic en el botón Formato y elija el formato deseado.
- Haga clic en Aceptar dos veces para cerrar ambos cuadros de diálogo y guardar la regla.
Para obtener una explicación más detallada de cada paso, consulte: Uso de fórmulas para el formato condicional de Excel.
Como resultado, Excel resalta todas las celdas con cadenas de texto:
Así es como se usan las funciones ISTEXT y ISNONTEXT en Excel. ¡Gracias por leer y espero verte en nuestro blog la próxima semana!