Usando la función ELEGIR en Excel

Función ELEGIR en Excel con ejemplos de fórmula

El tutorial explica la sintaxis y los usos básicos de la función ELEGIR y proporciona algunos ejemplos no triviales que muestran cómo usar una fórmula ELEGIR en Excel.

ELEGIR es una de esas funciones de Excel que pueden no parecer útiles por sí solas, pero combinadas con otras funciones brindan una serie de beneficios increíbles. En el nivel más básico, utiliza la función ELEGIR para obtener un valor de una lista especificando la posición de ese valor. Más adelante en este tutorial, encontrará varios usos avanzados que sin duda vale la pena explorar.

Función ELEGIR de Excel – sintaxis y usos básicos

La función ELEGIR en Excel está diseñada para devolver un valor de la lista en función de una posición específica.

La función está disponible en Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 y Excel 2007.

La sintaxis de la función ELEGIR es la siguiente:

ELEGIR(núm_índice, valor1, [value2]…)

Dónde:

núm_índice (requerido) – la posición del valor a devolver. Puede ser cualquier número entre 1 y 254, una referencia de celda u otra fórmula.

valor1, valor2, … – una lista de hasta 254 valores entre los que elegir. Se requiere Value1, otros valores son opcionales. Estos pueden ser números, valores de texto, referencias de celdas, fórmulas o nombres definidos.

Aquí hay un ejemplo de una fórmula ELEGIR en la forma más simple:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

La fórmula devuelve «Amy» porque index_num es 3 y «Amy» es el tercer valor de la lista:
Usando la función ELEGIR en Excel

Función ELEGIR de Excel – ¡3 cosas para recordar!

ELEGIR es una función muy simple y difícilmente encontrará dificultades para implementarla en sus hojas de trabajo. Si el resultado devuelto por su fórmula ELEGIR es inesperado o no es el resultado que estaba buscando, puede deberse a las siguientes razones:

  1. El número de valores para elegir está limitado a 254.
  2. Si index_num es menor que 1 o mayor que el número de valores en la lista, el #VALOR! se devuelve el error.
  3. Si el argumento index_num es una fracción, se trunca al entero más bajo.

Cómo usar la función ELEGIR en Excel – ejemplos de fórmulas

Los siguientes ejemplos muestran cómo ELEGIR puede ampliar las capacidades de otras funciones de Excel y proporcionar soluciones alternativas a algunas tareas comunes, incluso a aquellas que muchos consideran inviables.

Excel ELEGIR en lugar de IF anidados

Una de las tareas más frecuentes en Excel es devolver diferentes valores en función de una condición específica. En la mayoría de los casos, esto se puede hacer usando una instrucción IF anidada clásica. Pero la función ELEGIR puede ser una alternativa rápida y fácil de entender.

Ejemplo 1. Devuelve diferentes valores según la condición

Supongamos que tiene una columna de puntajes de estudiantes y desea etiquetar los puntajes según las siguientes condiciones:

Resultado Puntaje
Pobre 0 – 50
Satisfactorio 51 – 100
Bueno 101 – 150
Excelente más de 151

Una forma de hacer esto es anidar algunas fórmulas IF una dentro de la otra:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

Otra forma es elegir una etiqueta correspondiente a la condición:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Una fórmula ELEGIR como alternativa a los IF anidados

Cómo funciona esta fórmula:

En el argumento index_num, evalúa cada condición y devuelve VERDADERO si se cumple la condición, FALSO de lo contrario. Por ejemplo, el valor en la celda B2 cumple con las tres primeras condiciones, por lo que obtenemos este resultado intermedio:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

Dado que en la mayoría de las fórmulas de Excel, VERDADERO equivale a 1 y FALSO a 0, nuestra fórmula sufre esta transformación:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

Una vez realizada la operación de suma, tenemos:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

Como resultado, se devuelve el tercer valor de la lista, que es «Bueno».

Puntas:

  • Para que la fórmula sea más flexible, puede usar referencias de celda en lugar de etiquetas codificadas, por ejemplo:

    =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

  • Si ninguna de sus condiciones es VERDADERA, el argumento index_num se establecerá en 0, lo que obligará a su fórmula a devolver el #VALOR. error. Para evitar esto, simplemente ajuste ELEGIR en la función IFERROR de esta manera:

    =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Ejemplo 2. Realizar diferentes cálculos basados ​​en la condición

De manera similar, puede usar la función ELEGIR de Excel para realizar un cálculo en una serie de cálculos/fórmulas posibles sin anidar varias declaraciones IF una dentro de otra.

Como ejemplo, calculemos la comisión de cada vendedor en función de sus ventas:

Comisión Ventas
5% $0 a $50
7% $ 51 a $ 100
10% más de $101

Con el monto de las ventas en B2, la fórmula toma la siguiente forma:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

ELEGIR fórmula para realizar diferentes cálculos basados ​​en la condición

En lugar de codificar los porcentajes en la fórmula, puede consultar la celda correspondiente en su tabla de referencia, si hay alguna. Solo recuerda corregir las referencias usando el signo $.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

Fórmula ELEGIR de Excel para generar datos aleatorios

Como probablemente sepa, Microsoft Excel tiene una función especial para generar números enteros aleatorios entre los números superiores e inferiores que usted especifique: función ALEATORIO ENTRE. Anímelo en el argumento index_num de ELEGIR, y su fórmula generará casi todos los datos aleatorios que desee.

Por ejemplo, esta fórmula puede producir una lista de resultados de exámenes aleatorios:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

Fórmula ELEGIR de Excel para generar datos aleatorios

La lógica de la fórmula es obvia: ALEATORIO ENTRE genera números aleatorios del 1 al 4 y ELEGIR devuelve un valor correspondiente de la lista predefinida de cuatro valores.

Nota. RANDBETWEEN es una función volátil y se vuelve a calcular con cada cambio que realice en la hoja de trabajo. Como resultado, su lista de valores aleatorios también cambiará. Para evitar que esto suceda, puede reemplazar las fórmulas con sus valores mediante la función Pegado especial.

ELEGIR fórmula para hacer una búsqueda V izquierda

Si alguna vez realizó una búsqueda vertical en Excel, sabe que la función BUSCARV solo puede buscar en la columna más a la izquierda. En situaciones en las que necesite devolver un valor a la izquierda de la columna de búsqueda, puede usar la combinación ÍNDICE / COINCIDIR o engañar a BUSCARV anidando la función ELEGIR en él. Así es cómo:

Supongamos que tiene una lista de puntajes en la columna A, los nombres de los estudiantes en la columna B y desea recuperar el puntaje de un estudiante en particular. Dado que la columna de retorno está a la izquierda de la columna de búsqueda, una fórmula Vlookup normal devuelve el error #N/A:

Excel BUSCARV no puede mirar a la izquierda.

Para solucionar esto, obtenga la función ELEGIR para intercambiar las posiciones de las columnas, diciéndole a Excel que la columna 1 es B y la columna 2 es A:

=CHOOSE({1,2}, B2:B5, A2:A5)

Debido a que proporcionamos una matriz de {1,2} en el argumento index_num, la función ELEGIR acepta rangos en los argumentos de valor (normalmente, no lo hace).

Ahora, inserte la fórmula anterior en el argumento table_array de BUSCARV:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

Y voilà: ¡una búsqueda a la izquierda se realiza sin problemas!

Fórmula VLOOKUP/CHOOSE para hacer una búsqueda a la izquierda

ELEGIR fórmula para regresar el próximo día hábil

Si no está seguro de si debe ir a trabajar mañana o puede quedarse en casa y disfrutar de su merecido fin de semana, la función ELEGIR de Excel puede averiguar cuándo es el próximo día laboral.

Suponiendo que sus días laborales son de lunes a viernes, la fórmula es la siguiente:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

ELEGIR fórmula para regresar el siguiente día hábil después de hoy

Difícil a primera vista, después de una mirada más cercana, la lógica de la fórmula es fácil de seguir:

WEEKDAY(TODAY()) devuelve un número de serie correspondiente a la fecha de hoy, que va del 1 (domingo) al 7 (sábado). Este número va al argumento index_num de nuestra fórmula ELEGIR.

Valor1 – valor7 (1,1,1,1,1,3,2) determina cuántos días agregar a la fecha actual. Si hoy es domingo – jueves (index_num 1 – 5), agrega 1 para regresar al día siguiente. Si hoy es viernes (index_num 6), sumas 3 para volver el próximo lunes. Si hoy es sábado (index_num 7), sumas 2 para volver el próximo lunes nuevamente. Sí, es así de simple 🙂

ELEGIR fórmula para devolver un nombre de día/mes personalizado a partir de la fecha

En situaciones en las que desea obtener el nombre de un día en el formato estándar, como el nombre completo (lunes, martes, etc.) o el nombre corto (lunes, martes, etc.), puede usar la función TEXTO como se explica en este ejemplo: Obtenga el día de la semana a partir de la fecha en Excel.

Si desea devolver un día de la semana o un nombre de mes en un formato personalizado, use la función ELEGIR de la siguiente manera.

Para obtener un día de la semana:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

Para obtener un mes:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Donde A2 es la celda que contiene la fecha original.

ELEGIR fórmula para devolver un nombre de día/mes personalizado a partir de la fecha

Espero que este tutorial le haya dado algunas ideas sobre cómo puede usar la función ELEGIR en Excel para mejorar sus modelos de datos. ¡Gracias por leer y espero verte en nuestro blog la próxima semana!

Descargar libro de práctica

Deja un comentario

Tu dirección de correo electrónico no será publicada. Los campos obligatorios están marcados con *

Experto Geek - Tu Guía en Tendencias Tecnológicas