Mydefrag Your Way Featured

Cómo desfragmentar perfectamente sus discos duros con MyDefrag

Las partes principales de las unidades de disco duro son sus platos giratorios y los cabezales que leen y escriben datos en ellos. La parte exterior de esos platos en forma de disco, gracias a lo que nos enseña la Física, tienen una aceleración lineal más rápida. Además, se percibe un costo de rendimiento cuando los datos se distribuyen por toda su superficie.

MyDefrag puede estar casi extinguido, pero sigue siendo el único programa de este tipo que puede optimizar su disco duro exactamente como lo desea. Al igual que todos los desfragmentadores, reorganiza todas las partes de sus archivos, los empaqueta y corrige el bajo rendimiento cuando se distribuye por toda la superficie. También le permite configurar zonas, colocando sus archivos más importantes en la región exterior más rápida de la superficie del HDD. Solo tienes que decirle dónde va a través de un sencillo script.

Localice, descargue e instale MyDefrag

Desafortunadamente, MyDefrag no es compatible hoy en día y su sitio oficial está muerto. Sin embargo, aún puede encontrarlo en sitios populares de alojamiento de software, como ArchivoHipopótamo y MajorGeeks.

Instalación de Mydefrag a tu manera

Descargue e instale la última versión del programa, MyDefrag 4.3.1. Acepte todos los valores predeterminados durante la instalación y asegúrese de que «Seleccionar y activar MyDefrag ScreenSaver» no esté seleccionado.

Crear un nuevo guión

No controla cómo funciona MyDefrag a través de una interfaz gráfica o de opciones de línea de comandos: se hace con scripts simples. Ubique la subcarpeta scripts, que existe para este propósito en su directorio de instalación.

Nuevo guión de Mydefrag a tu manera

Haga clic derecho en este directorio y cree un nuevo archivo TXT en blanco. Asígnele el nombre que desee, pero cambie su extensión a «MyD», el valor predeterminado para los scripts de MyDefrag. Luego, ábralo en su editor de texto favorito.

Introducción al guión

Usaremos los existentes como base para un script que optimiza un disco duro lleno de juegos, colocando los archivos que afectan más a su rendimiento que otros en las partes más rápidas de la superficie del disco, moviendo los menos esenciales y no frecuentes. datos accedidos al otro extremo.

Introducción a la secuencia de comandos Mydefrag Your Way

La primera parte de su secuencia de comandos debe configurar las cosas de la siguiente manera. Tenga en cuenta que debe colocar cada parámetro y comando en una nueva línea individual. También tenga en cuenta que usaremos comentarios en el código, que comienzan con «//», para explicar las partes más crípticas de nuestro script.

Title("Title of your script")
Description("Short description of your script")
WriteLogfile("MyDefrag.log","LogHeader")
VolumeSelect
CommandlineVolumes()
VolumeActions
AppendLogfile("MyDefrag.log","LogBefore")

Configura tu primera zona

Al dividir la superficie del disco duro en zonas, MyDefrag le permite colocar archivos y carpetas específicos en las partes de su superficie que funcionan mejor o peor.

Zonas Mydefrag a tu manera

Configure las zonas seleccionando lo que debe ir en ellas:

// Zone 1 - Non-important, slow files
FileSelect // Select specific files.
  !include "file_list.txt"! // Select the files defined in file_list.txt.
FileActions // What MyDefrag will do with those files.
  MoveToEndOfDisk() // Move them to slower portion of the HDD since they are the unimportant ones
  AddGap(ZoneEnd + VolumeFree * 0.1 // Add a 0.1% size gap between that zone and the next one
FileEnd // End file selection for the specific zone

Configuración de más zonas

MyDefrag solo puede agrupar sus archivos, como otros desfragmentadores, si no configura ninguna zona, pero se perderá todo el sentido de su uso.

Mydefrag a tu manera Más zonas

Configuramos más zonas de la siguiente manera:

// Zone 2: Put directories together,  for quicker listing of the HDD's contents - same syntax as before
FileSelect 
  Directory(yes) // Define that we want to select directories, not files.
FileActions
  SortByName(Ascending) // Sort them by alphabetical order.
  AddGap(ZoneEnd + VolumeFree * 0.05)
FileEnd
 
// Zone 3: Typical, popular "game filetypes", for quicker game launching
FileSelect
Filename("_.exe")
OR Filename("_.dll")
OR Filename("_.ini")
OR Filename("_.conf")
OR Filename("_.cfg")
OR Filename("_.bat")
OR Filename("_.ico")
FileActions
  SortByName(Ascending)
  AddGap(ZoneEnd + VolumeFree * 0.1)
FileEnd
 
// Zone 4: Place the MFT and other special NTFS files right after our most important files
FileSelect
  SelectNtfsSystemFiles(yes)
FileActions
  PlaceNtfsSystemFiles(Ascending,MftSize * 0.01) // Move the selected NTFS system files and set the MFT to a %0.01 size.
  AddGap(ZoneEnd + VolumeFree * 0.01)
FileEnd
 
// Zone 5: Recently accessed files (for better performance of last games played).
FileSelect
  LastAccessEnabled(yes) and LastAccess(60 days ago,now)
FileActions
  SortByName(Ascending)
  AddGap(ZoneEnd + VolumeFree * 0.3)
FileEnd
 
// Zone 6: all other files.
FileSelect
  all
FileActions
  SortByName(Ascending)
  AddGap(ZoneEnd + VolumeFree)
FileEnd

guion final

Lo que sigue aquí es todo el guión final. Siéntase libre de copiarlo y pegarlo en su propio script, luego modificarlo como desee.

Title("Make Tech Easier's Games HDD Monthly")
Description("Optimize Game HDDs by moving temp, downloading, and non-important gaming-related files and directories to its end, leaving the faster HDD space for more important stuff.")
 
// Write the header to the logfile. See the "Settings.MyD" file for the definition of the "LogHeader" string.
WriteLogfile("MyDefrag.log","LogHeader")
 
// Select and process the volumes one by one.
VolumeSelect
  CommandlineVolumes()
VolumeActions
 
// Write the "before" statistics to the logfile. See the "Settings.MyD" file for the definition of the "LogBefore" string.
  AppendLogfile("MyDefrag.log","LogBefore")
 
// Zone 1 - Place Non-important, temp and ultra-large files at the end of the disk.
  FileSelect
    !include "file_list.txt"!
  FileActions
    MoveToEndOfDisk()
    AddGap(ZoneEnd + VolumeFree * 0.1)
  FileEnd
 
// Zone 2: Directories.
  FileSelect
    Directory(yes)
  FileActions
    SortByName(Ascending)
    AddGap(ZoneEnd + VolumeFree * 0.05)
  FileEnd
 
// Zone 3: Main Game Files (for quicker game launch).
  FileSelect
    Filename("*.exe")
	OR Filename("*.dll")
	OR Filename("*.ini")
	OR Filename("*.conf")
	OR Filename("*.cfg")
	OR Filename("*.BAT")
	OR Filename("*.ico")
  FileActions
    SortByName(Ascending)
    AddGap(ZoneEnd + VolumeFree * 0.1)
  FileEnd
 
//Zone 4: Place the MFT and some other special NTFS files.
  FileSelect
    SelectNtfsSystemFiles(yes)
  FileActions
    PlaceNtfsSystemFiles(Ascending,MftSize * 0.01)
    AddGap(ZoneEnd + VolumeFree * 0.01)
  FileEnd
 
// Zone 5: Recently accessed files (for better performance of last games played).
  FileSelect
    LastAccessEnabled(yes) and LastAccess(60 days ago,now)
  FileActions
    SortByName(Ascending)
    AddGap(ZoneEnd + VolumeFree * 0.3)
  FileEnd
 
// Zone 6: all other files.
  FileSelect
    all
  FileActions
    SortByName(Ascending)
    AddGap(ZoneEnd + VolumeFree)
  FileEnd
 
// Write the "after" statistics to the logfile. See the "Settings.MyD" file for the definition of the "LogAfter" string.
  AppendLogfile("MyDefrag.log","LogAfter")
 
VolumeEnd
 
// Write the footer to the logfile. See the "Settings.MyD" file for the definition of the "LogFooter" string.
AppendLogfile("MyDefrag.log","LogFooter")

Crear una lista de archivos de baja prioridad

¿Recuerdas cómo le dijimos a nuestro script que tuviera en cuenta una lista de archivos de baja prioridad, en formato TXT, antes de organizar nuestros archivos? Ahora es el momento de crear ese archivo.

Mydefrag Your Way Lista de baja prioridad

Haga clic derecho en la carpeta de scripts y cree un nuevo archivo TXT en blanco. Nómbrelo como «file_list.txt», el mismo nombre de archivo que usamos en el script.

Aquí hay una lista de muestra que puede copiar y usar. Cambie los directorios y archivos por otros que no le interesen.

  DirectoryName("Game_I_never_play_after_installing")
    OR DirectoryName("Another_game_I_keep_but_rarely_play")
    OR DirectoryName("Game_that_takes_up_almost_half_the_HDD")
    OR Filename("vc_redist.x64.exe")
    OR Filename("vcredist_x64.exe")
    OR Filename("vcredist_x64*.exe")
    OR Filename("*.iso")
    OR Filename("*.isz")
    OR Filename("*.mdf")
    OR Filename("*.cdi")
    OR Filename("*.pdf")
    OR Filename("*.bik")
    OR Filename("*.avi")
    OR Filename("*.wmv")
    OR Filename("*.bk2")
    OR Filename("*.mp4")
    OR Filename("*.rar")
    OR Filename("*.zip")
    OR Filename("*.7z")
    OR Filename("*.7z.*")

Ejecute su secuencia de comandos

Con los dos archivos que definen su lógica de desfragmentación listos, ¡es hora de ponerlos a trabajar! Ejecute MyDefrag y, si no hay ningún error tipográfico en ninguna parte, su secuencia de comandos debería aparecer entre las secuencias de comandos predeterminadas en la lista del programa.

Mydefrag a tu manera Ejecuta Mydefrag

Selecciónelo de la lista «Seleccione un script». Luego, como dice MyDefrag, «Seleccione 1 o más discos» de la segunda lista que le gustaría desfragmentar según las reglas de su secuencia de comandos. Haga clic en «Ejecutar» y espere algunas horas (o días, para HDD de Terabyte) para que haga su magia.

Eso es todo. Ha desfragmentado y optimizado su disco duro de la manera que desea, y ahora debería funcionar mejor y más rápido.

Relacionado:

Deja un comentario

Tu dirección de correo electrónico no será publicada. Los campos obligatorios están marcados con *

Experto Geek - Tu Guía en Tendencias Tecnológicas