El tutorial muestra cómo crear una calculadora de fechas en Excel exactamente para sus necesidades para encontrar una fecha N días a partir de hoy o antes, contando todos los días o solo los días hábiles.
¿Está buscando calcular la fecha de vencimiento que es exactamente dentro de 90 días? ¿O te preguntas qué fecha es 45 días después de hoy? ¿O necesita saber la fecha que ocurrió 60 días antes de hoy (contando solo los días hábiles y todos los días)?
Cualquiera que sea su tarea, este tutorial le enseñará cómo hacer su propia calculadora de fechas en Excel en menos de 5 minutos. Si no tiene tanto tiempo, puede usar nuestra calculadora en línea para encontrar la fecha que es el número especificado de días después o antes de hoy.
Calculadora de fechas en Excel Online
¿Quiere una solución rápida a «qué es 90 días a partir de hoy» o «qué es 60 días antes de hoy»? Escribe el número de días en la celda correspondiente, presiona Enter, e inmediatamente tendrás todas las respuestas:
Necesita calcular 30 días a partir de una fecha determinada o determinar 60 días hábiles antes de una cierta fecha? Entonces usa esta calculadora de fecha.
¿Tienes curiosidad por saber qué fórmulas se utilizan para calcular tus fechas? Los encontrará todos y muchos más en los siguientes ejemplos.
Cómo calcular 30/60/90 días a partir de hoy en Excel
Para encontrar una fecha a N días a partir de ahora, use la función HOY para devolver la fecha actual y agregarle la cantidad deseada de días.
Para obtener una fecha que ocurra exactamente dentro de 30 días a partir de hoy:=TODAY()+30
Para calcular 60 días a partir de hoy:=TODAY()+60
¿Qué fecha es dentro de 90 días a partir de ahora? Supongo que ya sabes cómo conseguirlo 🙂=TODAY()+90
Para hacer un generico hoy más N días fórmula, ingrese el número de días en alguna celda, digamos B3, y agregue esa celda a la fecha actual:
=TODAY()+B3
Ahora, sus usuarios pueden escribir cualquier número en la celda a la que se hace referencia y la fórmula se volverá a calcular en consecuencia. Como ejemplo, busquemos una fecha que ocurra dentro de 45 días a partir de hoy:
Cómo funciona esta fórmula
En su representación interna, Excel almacena las fechas como números de serie que comienzan con el 1 de enero de 1900, que es el número 1. Por lo tanto, la fórmula simplemente suma los dos números, el número entero representa la fecha de hoy y la cantidad de días que especifique. La función TODAY() es volátil y se actualiza automáticamente cada vez que se abre o se vuelve a calcular la hoja de trabajo; por lo tanto, cuando abra el libro de trabajo mañana, su fórmula se volverá a calcular para el día actual.
Al momento de escribir, la fecha de hoy es el 19 de abril de 2018, que está representada por el número de serie 43209. Para encontrar una fecha, digamos, dentro de 100 días, en realidad realiza los siguientes cálculos:
=TODAY() + 100
= April 19, 2018 + 100
= 43209 + 100
= 43309
Convierta el número de serie 43209 al formato de fecha y obtendrá el 28 de julio de 2018, que es exactamente 100 días después de hoy.
Cómo obtener 30/60/90 días antes de hoy en Excel
Para calcular N días antes de hoy, reste el número requerido de días de la fecha actual. Por ejemplo:
90 días antes de hoy:=TODAY()-90
60 días antes de hoy:=TODAY()-60
45 días antes de hoy:=TODAY()-45
O bien, haga un genérico hoy menos N días fórmula basada en una referencia de celda:
=TODAY()-B3
En la captura de pantalla a continuación, calculamos una fecha que ocurrió 30 días antes de hoy.
Cómo calcular N negocio después/antes de hoy
Como probablemente sepa, Microsoft Excel tiene algunas funciones para calcular los días hábiles en función de una fecha de inicio, así como entre dos fechas que especifique.
En los siguientes ejemplos, usaremos la función WORKDAY, que devuelve una fecha que ocurre un número determinado de días hábiles antes o antes de la fecha de inicio, excluyendo los fines de semana (sábado y domingo). Si sus fines de semana son diferentes, utilice la función WORKDAY.INTL que permite parámetros de fin de semana personalizados.
Entonces, para encontrar una fecha N días hábiles a partir de hoyutilice esta fórmula genérica:
DÍA LABORAL(HOY(), N días)
Aquí están algunos ejemplos:
10 días hábiles a partir de hoy=WORKDAY(TODAY(), 10)
30 días hábiles a partir de ahora=WORKDAY(TODAY(), 30)
5 días hábiles a partir de hoy=WORKDAY(TODAY(), 5)
para conseguir una cita N días hábiles antes de hoyusa esta fórmula:
DÍA LABORAL(HOY(), -N días)
Y aquí hay un par de fórmulas de la vida real:
90 días hábiles antes de hoy=WORKDAY(TODAY(), -90)
15 días hábiles antes de hoy=WORKDAY(TODAY(), -15)
Para que su fórmula sea más flexible, reemplace el número de días codificado con una referencia de celda, digamos B3:
N días hábiles a partir de hoy:=WORKDAY(TODAY(), B3)
N días hábiles antes de hoy:=WORKDAY(TODAY(), -B3)
De manera similar, puede sumar o restar días de la semana a/de un fecha daday su calculadora de fechas de Excel puede verse como este.
Cómo crear una calculadora de fechas en Excel
¿Recuerdas el Calculadora de fecha en línea de Excel mostrado al principio de este tutorial? Ahora conoce todas las fórmulas y puede replicarlas fácilmente en sus hojas de trabajo. Incluso puede crear algo más elaborado porque la versión de escritorio de Excel ofrece muchas más capacidades.
Para darle algunas ideas, diseñemos nuestra Calculadora de fecha de Excel ahora mismo.
En general, puede haber 3 opciones para calcular las fechas:
- Basado en la fecha de hoy o en una fecha específica
- Desde o antes de la fecha especificada
- Contar todos los días o solo los días laborables
Para proporcionar todas estas opciones a nuestros usuarios, agregamos tres controles de Cuadro de grupo (pestaña Desarrollador > Insertar > Controles de formulario > Cuadro de grupo) e insertamos dos botones de opción en cada cuadro de grupo. Luego, vincula cada grupo de botones a una celda separada (haga clic con el botón derecho en el botón > Control de formato > pestaña Control > Enlace de celda), que puede ocultar más tarde. En este ejemplo, las celdas vinculadas son D5, D9 y D14 (consulte la captura de pantalla a continuación).
Opcionalmente, puede ingresar la siguiente fórmula en B6 para insertar la fecha actual si se selecciona el botón Fecha de hoy. En realidad, no es necesario para nuestra fórmula de cálculo de fecha principal, solo una pequeña cortesía para sus usuarios para recordarles qué fecha es hoy:
=IF($D$5=1, TODAY(), "")
Finalmente, inserte la siguiente fórmula en B18 que verifica el valor en cada celda vinculada y calcula la fecha según las elecciones del usuario:
=IF(AND($D$5=1, $D$9=1, $D$14=1), TODAY()+$B$3, IF(AND($D$5=1, $D$9=1, $D$14=2), WORKDAY(TODAY(),$B$3), IF(AND($D$5=1, $D$9=2, $D$14=1), TODAY()-$B$3, IF(AND($D$5=1, $D$9=2, $D$14=2), WORKDAY(TODAY(),-$B$3), IF(AND($D$5=2, $D$9=1, $D$14=1), $B$7+$B$3, IF(AND($D$5=2, $D$9=1, $D$14=2), WORKDAY($B$7, $B$3), IF(AND($D$5=2, $D$9=2, $D$14=1), $B$7-$B$3, IF(AND($D$5=2, $D$9=2, $D$14=2), WORKDAY($B$7,-$B$3), ""))))))))
Puede parecer una fórmula monstruosa a primera vista, pero si la divide en declaraciones IF individuales, reconocerá fácilmente las fórmulas simples de cálculo de fechas que hemos discutido en los ejemplos anteriores.
Y ahora, selecciona las opciones deseadas, digamos, 60 días a partir de ahoray obtener el siguiente resultado:
Para echar un vistazo más de cerca a la fórmula y probablemente aplicarle ingeniería inversa a sus necesidades, le invitamos a descargar nuestro Calculadora de fecha para Excel.
Si está buscando algo más profesional, puede calcular rápidamente 90, 60, 45, 30 días a partir de ahora (o la cantidad de días que necesite) con nuestras herramientas de Excel.
Asistente de fecha y hora
Si ha tenido la oportunidad de pagar con nuestro Asistente de fecha y hora al menos una vez, sabe que puede sumar o restar instantáneamente días, semanas, meses o años (o cualquier combinación de estas unidades) a una fecha determinada, así como calcular la diferencia entre dos días. ¿Pero sabías que también puede calcular fechas basadas en hoy?
Como ejemplo, averigüemos qué fecha es 120 días de Este Dia:
- Ingrese la fórmula HOY () en alguna celda, digamos B1.
- Seleccione la celda donde desea generar el resultado, B2 en nuestro caso.
- Haga clic en el Asistente de fecha y hora en la pestaña Herramientas de Ablebits.
- En la pestaña Agregar, especifique cuántos días desea agregar a la fecha de origen (120 días en este ejemplo).
- Haga clic en el botón Insertar fórmula.
¡Eso es todo!
Como se muestra en la captura de pantalla anterior, la fórmula creada por el asistente es diferente de todas las fórmulas que hemos tratado, pero funciona igual de bien 🙂
Para obtener una fecha que ocurrió 120 días antes de hoy, cambie a la pestaña Restar y configure los mismos parámetros. O ingrese la cantidad de días en otra celda y dirija el asistente a esa celda:
Como resultado, obtendrá una fórmula universal que se vuelve a calcular automáticamente cada vez que ingresa una nueva cantidad de días en la celda de referencia.
Selector de fecha para Excel
Con nuestro Selector de fechas de Excel, no solo puede insertar fechas válidas en sus hojas de trabajo con un clic, ¡sino también calcularlas!
A diferencia del Asistente para fecha y hora, esta herramienta inserta fechas como estáticas valoresno fórmulas.
Por ejemplo, así es como puede obtener una fecha dentro de 21 días a partir de hoy:
- Haga clic en el Buscador de fechas en la pestaña Herramientas de Ablebits para habilitar un calendario desplegable en su Excel.
- Haga clic con el botón derecho en la celda donde desea insertar la fecha calculada y elija Seleccionar fecha del calendario del menú emergente.
- El calendario desplegable aparecerá en su hoja de trabajo con la fecha actual resaltada en azul, y haga clic en el botón de la calculadora en la esquina superior derecha:
- En el panel superior, haga clic en la unidad Día y escriba la cantidad de días que desea agregar, 21 en nuestro caso. De forma predeterminada, la calculadora realiza la operación de suma (observe el signo más en el panel de visualización). Si desea restar días a partir de hoy, haga clic en el signo menos en el panel inferior.
- Finalmente, haga clic en
para mostrar la fecha calculada en el calendario. O bien, presione la tecla Intro o haga clic en 
para insertar la fecha en una celda:
para mostrar la fecha calculada en el calendario. O bien, presione la tecla Intro o haga clic en 
para insertar la fecha en una celda:
Cómo resaltar fechas a 30, 60 y 90 días a partir de hoy
Al calcular las fechas de vencimiento o de vencimiento, es posible que desee que los resultados sean más visuales codificando con colores las fechas según la cantidad de días antes del vencimiento. Esto se puede hacer con formato condicional de Excel.
Como ejemplo, hagamos 4 reglas de formato condicional basadas en estas fórmulas:
- Verde: más de 90 días a partir de ahora
=C2>TODAY()+90 - Amarillo: entre 60 y 90 días a partir de hoy
=C2>TODAY()+60 - Ámbar: entre 30 y 60 días a partir de hoy
=C2>TODAY()+30 - Rojo: menos de 30 días a partir de ahora
=C2<TODAY()+30
Donde C2 es la fecha de caducidad más alta.
Estos son los pasos para crear una regla basada en fórmulas:
- Seleccione todas las celdas con las fechas de caducidad (B2:B10 en este ejemplo).
- En la pestaña Inicio, en el grupo Estilos, haga clic en Formato condicional > Nueva regla…
- En el cuadro de diálogo Nueva regla de formato, seleccione Use una fórmula para determinar qué celdas formatear.
- En el cuadro Formatear valores donde esta fórmula es verdadera, ingrese su fórmula.
- Hacer clic Formato…cambie a la pestaña Relleno y seleccione el color deseado.
- Haga clic en Aceptar dos veces para cerrar ambas ventanas.
¡Nota IMPORTANTE! Para que los códigos de color se apliquen correctamente, las reglas deben ordenarse exactamente en este orden: verde, amarillo, ámbar, rojo:
Si no quiere preocuparse por el orden de las reglas, use las siguientes fórmulas que definen cada condición exactamente y organice las reglas como desee:
Verde: más de 90 días a partir de ahora:=C2>TODAY()+90
Amarillo: entre 60 y 90 días a partir de hoy:=AND(C2>=TODAY()+60, C2<=TODAY()+90)
Ámbar: entre 30 y 60 días a partir de hoy:=AND(C2>=TODAY()+30, C2<TODAY()+60)
Rojo: menos de 30 días a partir de hoy:=C2<TODAY()+30
Consejo. Para incluir o excluir los valores límite de una determinada regla, utilice los operadores menor que (<), menor o igual que (<=), mayor que (>), mayor o igual que (<=) como mejor le parezca. .
De manera similar, puede resaltar fechas pasadas que ocurrió 30, 60 o hace 90 días a partir de hoy.
- Rojo: más de 90 días antes de hoy:
=B2<TODAY()-90 - Ámbar: entre 90 y 60 días antes de hoy:
=AND(B2>=TODAY()-90, B2<=TODAY()-60) - Amarillo: entre 60 y 30 días antes de hoy:
=AND(B2>TODAY()-60, B2<=TODAY()-30) - Verde: menos de 30 días antes de hoy:
=B2>TODAY()-30
Puede encontrar más ejemplos de formato condicional para fechas aquí: Cómo formatear condicionalmente fechas y horas en Excel.
Así es como se calculan las fechas que son 90, 60, 30 o n días desde/antes de hoy en Excel. Para ver de cerca las fórmulas y las reglas de formato condicional que se analizan en este tutorial, lo invito a descargar nuestro libro de trabajo de muestra a continuación. ¡Gracias por leernos y esperamos verte en nuestro blog la próxima semana!
Cuaderno de ejercicios para descargar
(archivo .xlsx)